QBanlist Helper

[Ventox]

שם הקוד: QBanlist Helper
יוצר: Ventox
גירסא: 1.0
תיאור: מאפשר שליטה נוחה יותר בQ באנים שבערוץ.
הפעלה: קליק ימני QBanlist by Ventox או /qb
תמונה:

קוד: בחר הכל

;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;; Q Banlist By Ventox [/qb ;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;

dialog qb {
  title "Q Banlist By Ventox [/qb]"
  size -1 -1 172 79
  option dbu
  list 1, 0 2 137 65, size
  button "Channel", 2, 138 2 33 12
  button "Add", 3, 138 15 33 12
  button "Rem.", 4, 138 28 33 12
  button "Clear", 5, 138 41 33 12
  button "Refresh", 6, 138 54 33 12
  edit "", 7, 0 68 137 10, read autohs
  edit "", 8, 137 68 34 10, read autohs
}

alias qb { if (!$dialog(qb)) dialog -m qb qb }
On *:Dialog:qb:sclick:*: {
  if ($did == 2) { var %x = $input(Type Channel,e,Type Channel) | if (%x) && ($chr(35) $+ * iswm %x) { .enable #QBanlist | .msg Q banlist %x | did -r $dname 1 | did -b $dname 3,4,5,6 | did -ra $dname 7 Getting banlist ... | set %Qb.Channel %x | did -e $dname 6 | did -ra $dname 8 %Qb.channel | unset %Qb.bans | unset %Qb.start } }
  elseif ($did == 6) && (%Qb.channel) && ($chr(35) $+ * iswm %Qb.channel) { .enable #QBanlist | did -ra $dname 7 Refreshing banlist ... | did -r $dname 1 | did -b $dname 3,4,5,6 | .msg Q banlist %Qb.channel | unset %Qb.bans | unset %Qb.start }
  elseif ($did == 1) && ($did($dname,1).seltext) { .enable #QBanlist | did -e $dname 4,5 }
  elseif ($did == 3) && (%Qb.channel) { var %x = $input(Type mask to ban.,e,Type mask to ban.) | if (%x) { .enable #QBanlist | Set %Qb.ban %x | .msg Q ban %Qb.channel %x } }
  elseif ($did == 4) && (%Qb.channel) && ($did($dname,1).seltext) { .enable #QBanlist | Set %Qb.banrm $did($dname,1).sel | did -ra $dname 7 Removing $did($dname,1).seltext ... | .msg Q bandel %Qb.channel $did($dname,1).seltext }
  elseif ($did == 5) && (%Qb.channel) { var %x = $Input(Are you sure to banclear?,y,Are you sure to banclear?) | if (%x == $true) { .enable #QBanlist | Set %Qb.banclear on | .msg Q banclear %Qb.channel } } 
}
On *:Dialog:qb:init:*: { unset %Qb.* | did -b $dname 6,5,4,3 | .disable #QBanlist }
On *:Dialog:qb:close:*: { unset %Qb.* | .disable #QBanlist }
#QBanlist off
On ^*:Notice:*:?: {
  haltdef
  if ($nick == Q) && ($dialog(qb)) {
    if (You do not have sufficient access on %Qb.Channel to use *. iswm $1-) { .disable #QBanlist | did -ra qb 7 You do not have sufficient access to use $11 }
    elseif ($1- == Done.) {
      if (%Qb.ban) { .disable #QBanlist | did -ra qb 7 Done, banned. | did -a qb 1 %Qb.ban | unset %Qb.ban }
      elseif (%Qb.banclear == on) { .disable #QBanlist | did -r qb 1 | did -ra qb 7 Done, all the bans removed from %Qb.channel $+ . | unset %Qb.banclear }
    }
    elseif ($1- == Channel %Qb.Channel is unknown or suspended.) { .disable #QBanlist | did -e qb 6 | did -ra qb 7 $1- }
    elseif ($1- == Registered bans on %Qb.channel $+ :) { Set %Qb.start ON }
    elseif (Can't find ban * on %Qb.channel $+ . iswm $1-) { .disable #QBanlist | did -ra qb 7 $1- }
    elseif (Removed * ban * from %Qb.channel $+ . iswm $1-) { .disable #QBanlist | did -ra qb 7 Done, ban removed. | did -d qb 1 %Qb.banrm | unset %Qb.banrm }
    elseif ($1- == No bans on %Qb.channel $+ .) { .disable #QBanlist | did -e qb 3,5,6 | did -ra qb 7 $1- }
    elseif ($chr(35) $+ * iswm $1) && ($remove($1,$chr(35)) isnum) && ($4) && (%Qb.start == ON) { inc %Qb.bans | did -a qb 1 $2 }
    elseif ($1- == End of list.) && (%Qb.start == ON) { .disable #QBanlist | did -e qb 3,5,6 | did -ra qb 7 Total bans: %Qb.bans | unset %Qb.start | unset %Qb.bans }
  }
}
#QBanlist end
menu * {
  Q Banlist By Ventox { qb }
}

;; /End Of Q Banlist By Ventox [/qb] ;


[Ohad]

באמת קוד נחמד ושימושי מאוד וגם אחלה עיצוב של הדיאלוג
רק הייתי מציע לך:

• כאשר ה-active הוא ערוץ ברשת שמחוברת כרגע, אז אוטומטית לשאוב את רשימת הבאנים.
• להוסיף כפתור יציאה.

[uns]

עיצוב מושלם, מארגן ומסדר בצורה נוחה.

[XtrAp]

יפה מאוד!

[Nixxo]

יפה טל...!